###########################################################################
#
# configure -- Configure script for runtime-src
#
# By Michael Dewsnip
#
# Copyright (C) 2010  DL Consulting Ltd.
#
###########################################################################


AC_INIT([greenstone2-runtime-src], [2.84], [greenstone@cs.waikato.ac.nz])
AC_CONFIG_AUX_DIR([.])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([-Wall -Werror foreign no-define])

# This package requires the crypt library
AC_HAVE_LIBRARY(crypt)

# This package requires C++ compilation and library creation
AC_PROG_CXX
AC_PROG_INSTALL
AC_PROG_RANLIB

# Check for 64-bit machines
AC_CANONICAL_HOST
AC_MSG_CHECKING(if architecture is 64-bit)
arch_64bit=no
case "$host_cpu" in
  x86_64) arch_64bit=yes ;;
esac
if test "$arch_64bit" = yes; then
  AC_MSG_RESULT(yes)
  if test -z "$COMPAT32BITFLAGS" ; then
    COMPAT32BITFLAGS="-m32"
  fi
else
  AC_MSG_RESULT(no)
fi
AC_SUBST(COMPAT32BITFLAGS)

# Option: Lucene support (enabled by default)
AC_ARG_ENABLE([lucene], [AS_HELP_STRING([--disable-lucene], [Disable Lucene support])], [], [enable_lucene=yes])
if test "x$enable_lucene" != xno; then
  AC_DEFINE(ENABLE_LUCENE, 1, [Lucene support])
fi
AM_CONDITIONAL(ENABLE_LUCENE, test "x$enable_lucene" != xno)

# Option: SQLite support (enabled by default)
AC_ARG_ENABLE([sqlite], [AS_HELP_STRING([--disable-sqlite], [Disable SQLite support])], [], [enable_sqlite=yes])
if test "x$enable_sqlite" != xno; then
  AC_DEFINE(USE_SQLITE, 1, [SQLite support])
fi
AM_CONDITIONAL(USE_SQLITE, test "x$enable_sqlite" != xno)

# Generate the Makefiles for this package
AC_OUTPUT(Makefile src/colservr/Makefile src/protocol/Makefile src/recpt/Makefile src/oaiservr/Makefile)