###########################################################################
#
# GreenstoneSQLPlugout.pm -- plugout module for writing all or some the 
# Greenstone document format (metadata and/or fulltext) into a (My)SQL db.
# The rest is then still written out by GreenstoneXMLPlugout as usual.
# A component of the Greenstone digital library software
# from the New Zealand Digital Library Project at the 
# University of Waikato, New Zealand.
#
# Copyright (C) 2006 New Zealand Digital Library Project
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
###########################################################################

package GreenstoneSQLPlugout;

use strict;
no strict 'refs';
no strict 'subs';

use GreenstoneXMLPlugout;
use docprint;
use gsmysql;

use DBI; # the central package for this plugout

#use unicode;

# This plugout does not output the metadata and/or fulltxt xml to a file,
# but outputs rows into a MySQL db table for metadata and/or a db table for fulltxt

sub BEGIN {
    @GreenstoneSQLPlugout::ISA = ('GreenstoneXMLPlugout');
}


my $process_mode_list =
    [ { 'name' => "meta_only",
        'desc' => "{GreenstoneSQLPlug.process_mode.meta_only}" },      
      { 'name' => "text_only",
        'desc' => "{GreenstoneSQLPlug.process_mode.text_only}" },
      { 'name' => "all",
        'desc' => "{GreenstoneSQLPlug.process_mode.all}" } ];

my $rollback_on_cancel_list =
    [ { 'name' => "true",
        'desc' => "{common.true}" },      
      { 'name' => "false",
        'desc' => "{common.false}" } ];

# The following are the saveas.options:
my $arguments = [ 
    { 'name' => "process_mode", 
      'desc' => "{GreenstoneSQLPlug.process_mode}",
      'type' => "enum",
      'list' => $process_mode_list,
      'deft' => "all",
      'reqd' => "no",
      'hiddengli' => "no"},
    { 'name' => "rollback_on_cancel", 
      'desc' => "{GreenstoneSQLPlug.rollback_on_cancel}",
      'type' => "enum",
      'list' => $rollback_on_cancel_list,
      'deft' => "false", # better default than true
      'reqd' => "no",
      'hiddengli' => "no"},
    { 'name' => "db_driver", 
      'desc' => "{GreenstoneSQLPlug.db_driver}",
      'type' => "string",	
      'deft' => "mysql",
      'reqd' => "yes"},
    { 'name' => "db_client_user", 
      'desc' => "{GreenstoneSQLPlug.db_client_user}",
      'type' => "string",	
      'deft' => "root",
      'reqd' => "yes"},
    { 'name' => "db_client_pwd", 
      'desc' => "{GreenstoneSQLPlug.db_client_pwd}",
      'type' => "string",
      'deft' => "",
      'reqd' => "no"}, # pwd not required: can create mysql accounts without pwd
    { 'name' => "db_host", 
      'desc' => "{GreenstoneSQLPlug.db_host}",
      'type' => "string",
      'deft' => "127.0.0.1", # localhost doesn't work for us, but 127.0.0.1 works. See gsmysql.pm
      'reqd' => "yes"},
    { 'name' => "db_port", 
      'desc' => "{GreenstoneSQLPlug.db_port}",
      'type' => "string", # NOTE: make this int? No default for port, since it's not a required connection param
      'reqd' => "no"}
    ];

my $options = { 'name'     => "GreenstoneSQLPlugout",
		'desc'     => "{GreenstoneSQLPlugout.desc}",
		'abstract' => "no",
		'inherits' => "yes",
		'args'     => $arguments };

##### This entire class is called only during import.pl #####

##### Overridden methods #####

sub new {
    my ($class) = shift (@_);
    my ($plugoutlist, $inputargs,$hashArgOptLists) = @_;
    push(@$plugoutlist, $class);

    push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});
    push(@{$hashArgOptLists->{"OptList"}},$options);

    my $self = new GreenstoneXMLPlugout($plugoutlist,$inputargs,$hashArgOptLists);
    
    if ($self->{'info_only'}) {	
        # don't worry about any options etc
        return bless $self, $class;
    }
    
    return bless $self, $class;
}

# connect here and ensure all tables and databases exist
sub begin {

    my $self= shift (@_);
    
    my $db_params = {
	'collection_name' => $ENV{'GSDLCOLLECTION'},
	'verbosity' => $self->{'verbosity'} || 0
	
    };

    my $gs_sql = new gsmysql($db_params);

    # if autocommit is set, there's no rollback support
    my $autocommit = ($self->{'rollback_on_cancel'} eq "false") ? 1 : 0;
    
    # try connecting to the mysql db, die if that fails
    # So don't bother preparing GreenstoneXMLPlugout by calling superclass' begin() yet
    if(!$gs_sql->connect_to_db({
	'db_driver' => $self->{'db_driver'},
	'db_client_user' => $self->{'db_client_user'},
	'db_client_pwd' => $self->{'db_client_pwd'},
	'db_host' => $self->{'db_host'},
	'db_port' => $self->{'db_port'}, # undef by default, can leave as is
	'autocommit' => $autocommit
			       })
	)
    {
	# This is fatal for the plugout, let's terminate here
	# PrintError would already have displayed the warning message on connection fail	
	die("Could not connect to db. Can't proceed.\n");
    }

    my $db_name = $self->{'site'} || "greenstone2"; # one database per GS3 site, for GS2 the db is called greenstone2
    my $proc_mode = $self->{'process_mode'};
    

    my $success = $gs_sql->use_db($db_name);
    
    if($success && $proc_mode ne "text_only") {
	$success = $gs_sql->ensure_meta_table_exists();
    }    
    if($success && $proc_mode ne "meta_only") {
	$success = $gs_sql->ensure_fulltxt_table_exists();
    }
    
    if(!$success) {	
	# This is fatal for the plugout, let's terminate here after disconnecting again
	# PrintError would already have displayed the warning message on load fail
	# And on die() perl will call gsmysql destroy which will ensure a disconnect() from db
	die("Could not use db $db_name and/or prepare its tables. Can't proceed.\n");
    }

    # store the DBI wrapper instance
    $self->{'gs_sql'} = $gs_sql;
    
    
    # If setting up connection to sql db failed, we'd have terminated and wouldn't come up to here
    # and wouldn't have bothered preparing GreenstoneXMLPlugout by calling superclass' begin().
    # Finally, can call begin on super - important as doc.xml is opened as a group etc
    
    $self->SUPER::begin(@_);
}

# disconnect from database here, see inexport.pm
sub end
{
    my $self = shift(@_);

    # do the superclass stuff first, as any sql db failures should not prevent superclass cleanup
    $self->SUPER::end(@_);    

    # Important to call finished():
    # it will disconnect from db if this is the last gsmysql instance,
    # and it will commit to db before disconnecting if rollbback_on_cancel turned on
    $self->{'gs_sql'}->finished();
    delete $self->{'gs_sql'}; # key gs_sql no longer exists, not just the value being undef
}

# Produce files called docsql.xml instead of doc.xml
sub get_doc_xml_filename {
    my $self = shift (@_);
    my ($doc_obj) = @_;
    
    return "docsql.xml";
}

# overriding to store doc OID as attribute of top level element: <Archive docoid="oid">
sub output_xml_header {
    my $self = shift (@_);
    my ($outhandle, $doc_oid) = @_;

    print $outhandle '<?xml version="1.0" encoding="utf-8" standalone="no"?>' . "\n";
    print $outhandle "<!DOCTYPE Archive SYSTEM \"http://greenstone.org/dtd/Archive/1.0/Archive.dtd\">\n";
    print $outhandle "<Archive docoid=\"$doc_oid\">\n";
}
 
# saveas() only generates the content in archives dir and in the SQL database
sub saveas {
    my $self = shift (@_);
    my ($doc_obj, $doc_dir) = @_;

    my $proc_mode = $self->{'process_mode'};
    
    # 1. pre save out and saving debug handle

    # must call superclass (pre/post) saveas methods, as they handle assoc_files too
    my ($docxml_outhandler, $output_file) = $self->SUPER::pre_saveas(@_);

    $self->{'debug_outhandle'} = $docxml_outhandler if ($self->{'debug'}); # STDOUT if debug

    # 2. overriding saving behaviour to do what the superclass does (writing out doc.xml files,
    # under new name of docsql.xml, with breadcrumbs pointing to sql db) PLUS saving to sql db    

    # NOTE: if proc_mode == all, then "breadcrumbs" (statements pointing viewer to the sql db
    # for contents) go into both meta and txt elements of doc.xml (docsql.xml specifically): 
	
    # write the INVERSE into doc.xml as to what is written to the SQL db    
    my $docxml_output_options = { 'output' => docprint::OUTPUT_NONE };
    if($proc_mode eq "meta_only" ) { # since only meta to go into MySQL db, text will go into docxml
	$docxml_output_options->{'output'} = docprint::OUTPUT_TEXT_ONLY;
    } elsif($proc_mode eq "text_only" ) { # since only full text to go into MySQL db, meta will go into docxml
	$docxml_output_options->{'output'} = docprint::OUTPUT_META_ONLY;
    }
    
    # now we've prepared to write out whatever is meant to go into docxml
    # and can do actual the steps superclass GreenstoneXMLPlugout carries out to write out docxml
    # So: write out the doc xml file, "docsql.xml", for the current document
    my $section_text = &docprint::get_section_xml($doc_obj, $docxml_output_options);
    print $docxml_outhandler $section_text;    
    
    
    # We also write out whatever needs to go into the MySQL database
    $self->write_meta_and_text($doc_obj);

    
    # 3. post save out 
    $self->SUPER::post_saveas($doc_obj, $doc_dir, $docxml_outhandler, $output_file);
    
    
    # database connection is closed once, in end() method
    # We're not opening and closing over and over for each doc during a single build
}

##### New methods, not inherited  #####

# write meta and/or text PER DOC out to DB
sub write_meta_and_text {
    my $self = shift (@_);
    my ($doc_obj) = @_;
    my $doc_oid = $doc_obj->get_OID(); # this method processes a single doc at a time, so it uses the same OID throughout
    my $root_section = $doc_obj->get_top_section();

    $self->recursive_write_meta_and_text($doc_obj, $doc_oid, $root_section);
}

sub recursive_write_meta_and_text {
    my $self = shift (@_);
    my ($doc_obj, $doc_oid, $section) = @_;    

    # If section=ROOT, write "root" as section name into table
    # doc->get_top_section() is the name of the doc root section, which is ""
    my $section_name = ($section eq "") ? "root" : $section;
    
    my $section_ptr = $doc_obj->_lookup_section ($section);
    return "" unless defined $section_ptr;

    my $debug_out = $self->{'debug_outhandle'};

    my $gs_sql = $self->{'gs_sql'};
    my $proc_mode = $self->{'process_mode'};
    if($proc_mode eq "all" || $proc_mode eq "meta_only" ) {
	
	##binmode(STDERR, ":utf8"); # shouldn't be necessary as we call &unicode::utf8decomp() to avoid wide-character warnings by printing wide chars as unicode codepoints
	#print STDERR "###### dc.Title: ".&unicode::utf8decomp($doc_obj->get_metadata_element($doc_obj->get_top_section(), "dc.Title"))."\n";
	
	foreach my $data (@{$section_ptr->{'metadata'}}) {
	    my $meta_name = $data->[0];

	    # Treat db like a text file instead of an html/xml file: don't need to escape text
	    # going into it, unlike with doc(sql).xml
	    my $meta_value = $data->[1];
		
	    # Write out the current section's meta to collection db's METADATA table	    
	    
	    # For each set of values to write to meta table, this next method call will
	    # efficiently execute an insert SQL statement (using a prepared insert statement), 
	    # filling in the values
	    # OR if debugging, then it will print the SQL insert statement but not execute it
	    # (a behaviour following what the GS XML Plugout superclass does on debug)
	    
	    $gs_sql->insert_row_into_metadata_table($doc_oid, $section_name, $meta_name, $meta_value, $self->{'debug'});
	}
    }
    
    
    if($proc_mode eq "all" || $proc_mode eq "text_only" ) {

	# See above, no need to html-escape for db
	my $section_text = $section_ptr->{'text'};
	
	# fulltxt column can be SQL NULL. undef value for $section_text gets written out as NULL:
	# https://stackoverflow.com/questions/12708633/which-one-represents-null-undef-or-empty-string
	# The following will do the SQL insertion
	# or if debug, the following will print the SQL insert stmt without executing it
	$gs_sql->insert_row_into_fulltxt_table($doc_oid, $section_name, \$section_text, $self->{'debug'});
    
    }
    
    # output all subsections: RECURSIVE CALL
    foreach my $subsection (@{$section_ptr->{'subsection_order'}}) {
	$self->recursive_write_meta_and_text($doc_obj, $doc_oid, "$section.$subsection");
    }
}


1;